home *** CD-ROM | disk | FTP | other *** search
/ The Arsenal Files 8 / The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO / g_quake / progs106.zip / WEAPONS.QC < prev    next >
Text File  |  1996-09-30  |  25KB  |  1,293 lines
  1. /*
  2. */
  3. void (entity targ, entity inflictor, entity attacker, float damage) T_Damage;
  4. void () player_run;
  5. void(entity bomb, entity attacker, float rad, entity ignore) T_RadiusDamage;
  6. void(vector org, vector vel, float damage) SpawnBlood;
  7. void() SuperDamageSound;
  8.  
  9.  
  10. // called by worldspawn
  11. void() W_Precache =
  12. {
  13.     precache_sound ("weapons/r_exp3.wav");    // new rocket explosion
  14.     precache_sound ("weapons/rocket1i.wav");    // spike gun
  15.     precache_sound ("weapons/sgun1.wav");
  16.     precache_sound ("weapons/guncock.wav");    // player shotgun
  17.     precache_sound ("weapons/ric1.wav");    // ricochet (used in c code)
  18.     precache_sound ("weapons/ric2.wav");    // ricochet (used in c code)
  19.     precache_sound ("weapons/ric3.wav");    // ricochet (used in c code)
  20.     precache_sound ("weapons/spike2.wav");    // super spikes
  21.     precache_sound ("weapons/tink1.wav");    // spikes tink (used in c code)
  22.     precache_sound ("weapons/grenade.wav");    // grenade launcher
  23.     precache_sound ("weapons/bounce.wav");        // grenade bounce
  24.     precache_sound ("weapons/shotgn2.wav");    // super shotgun
  25. };
  26.  
  27. float() crandom =
  28. {
  29.     return 2*(random() - 0.5);
  30. };
  31.  
  32. /*
  33. ================
  34. W_FireAxe
  35. ================
  36. */
  37. void() W_FireAxe =
  38. {
  39.     local    vector    source;
  40.     local    vector    org;
  41.  
  42.     makevectors (self.v_angle);
  43.     source = self.origin + '0 0 16';
  44.     traceline (source, source + v_forward*64, FALSE, self);
  45.     if (trace_fraction == 1.0)
  46.         return;
  47.     
  48.     org = trace_endpos - v_forward*4;
  49.  
  50.     if (trace_ent.takedamage)
  51.     {
  52.         trace_ent.axhitme = 1;
  53.         SpawnBlood (org, '0 0 0', 20);
  54.         T_Damage (trace_ent, self, self, 20);
  55.     }
  56.     else
  57.     {    // hit wall
  58.         sound (self, CHAN_WEAPON, "player/axhit2.wav", 1, ATTN_NORM);
  59.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  60.         WriteByte (MSG_BROADCAST, TE_GUNSHOT);
  61.         WriteCoord (MSG_BROADCAST, org_x);
  62.         WriteCoord (MSG_BROADCAST, org_y);
  63.         WriteCoord (MSG_BROADCAST, org_z);
  64.     }
  65. };
  66.  
  67.  
  68. //============================================================================
  69.  
  70.  
  71. vector() wall_velocity =
  72. {
  73.     local vector    vel;
  74.     
  75.     vel = normalize (self.velocity);
  76.     vel = normalize(vel + v_up*(random()- 0.5) + v_right*(random()- 0.5));
  77.     vel = vel + 2*trace_plane_normal;
  78.     vel = vel * 200;
  79.     
  80.     return vel;
  81. };
  82.  
  83.  
  84. /*
  85. ================
  86. SpawnMeatSpray
  87. ================
  88. */
  89. void(vector org, vector vel) SpawnMeatSpray =
  90. {
  91.     local    entity missile, mpuff;
  92.     local    vector    org;
  93.  
  94.     missile = spawn ();
  95.     missile.owner = self;
  96.     missile.movetype = MOVETYPE_BOUNCE;
  97.     missile.solid = SOLID_NOT;
  98.  
  99.     makevectors (self.angles);
  100.  
  101.     missile.velocity = vel;
  102.     missile.velocity_z = missile.velocity_z + 250 + 50*random();
  103.  
  104.     missile.avelocity = '3000 1000 2000';
  105.     
  106. // set missile duration
  107.     missile.nextthink = time + 1;
  108.     missile.think = SUB_Remove;
  109.  
  110.     setmodel (missile, "progs/zom_gib.mdl");
  111.     setsize (missile, '0 0 0', '0 0 0');        
  112.     setorigin (missile, org);
  113. };
  114.  
  115. /*
  116. ================
  117. SpawnBlood
  118. ================
  119. */
  120. void(vector org, vector vel, float damage) SpawnBlood =
  121. {
  122.     particle (org, vel*0.1, 73, damage*2);
  123. };
  124.  
  125. /*
  126. ================
  127. spawn_touchblood
  128. ================
  129. */
  130. void(float damage) spawn_touchblood =
  131. {
  132.     local vector    vel;
  133.  
  134.     vel = wall_velocity () * 0.2;
  135.     SpawnBlood (self.origin + vel*0.01, vel, damage);
  136. };
  137.  
  138.  
  139. /*
  140. ================
  141. SpawnChunk
  142. ================
  143. */
  144. void(vector org, vector vel) SpawnChunk =
  145. {
  146.     particle (org, vel*0.02, 0, 10);
  147. };
  148.  
  149. /*
  150. ==============================================================================
  151.  
  152. MULTI-DAMAGE
  153.  
  154. Collects multiple small damages into a single damage
  155.  
  156. ==============================================================================
  157. */
  158.  
  159. entity    multi_ent;
  160. float    multi_damage;
  161.  
  162. void() ClearMultiDamage =
  163. {
  164.     multi_ent = world;
  165.     multi_damage = 0;
  166. };
  167.  
  168. void() ApplyMultiDamage =
  169. {
  170.     if (!multi_ent)
  171.         return;
  172.     T_Damage (multi_ent, self, self, multi_damage);
  173. };
  174.  
  175. void(entity hit, float damage) AddMultiDamage =
  176. {
  177.     if (!hit)
  178.         return;
  179.     
  180.     if (hit != multi_ent)
  181.     {
  182.         ApplyMultiDamage ();
  183.         multi_damage = damage;
  184.         multi_ent = hit;
  185.     }
  186.     else
  187.         multi_damage = multi_damage + damage;
  188. };
  189.  
  190. /*
  191. ==============================================================================
  192.  
  193. BULLETS
  194.  
  195. ==============================================================================
  196. */
  197.  
  198. /*
  199. ================
  200. TraceAttack
  201. ================
  202. */
  203. void(float damage, vector dir) TraceAttack =
  204. {
  205.     local    vector    vel, org;
  206.     
  207.     vel = normalize(dir + v_up*crandom() + v_right*crandom());
  208.     vel = vel + 2*trace_plane_normal;
  209.     vel = vel * 200;
  210.  
  211.     org = trace_endpos - dir*4;
  212.  
  213.     if (trace_ent.takedamage)
  214.     {
  215.         SpawnBlood (org, vel*0.2, damage);
  216.         AddMultiDamage (trace_ent, damage);
  217.     }
  218.     else
  219.     {
  220.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  221.         WriteByte (MSG_BROADCAST, TE_GUNSHOT);
  222.         WriteCoord (MSG_BROADCAST, org_x);
  223.         WriteCoord (MSG_BROADCAST, org_y);
  224.         WriteCoord (MSG_BROADCAST, org_z);
  225.     }
  226. };
  227.  
  228. /*
  229. ================
  230. FireBullets
  231.  
  232. Used by shotgun, super shotgun, and enemy soldier firing
  233. Go to the trouble of combining multiple pellets into a single damage call.
  234. ================
  235. */
  236. void(float shotcount, vector dir, vector spread) FireBullets =
  237. {
  238.     local    vector direction;
  239.     local    vector    src;
  240.     
  241.     makevectors(self.v_angle);
  242.  
  243.     src = self.origin + v_forward*10;
  244.     src_z = self.absmin_z + self.size_z * 0.7;
  245.  
  246.     ClearMultiDamage ();
  247.     while (shotcount > 0)
  248.     {
  249.         direction = dir + crandom()*spread_x*v_right + crandom()*spread_y*v_up;
  250.  
  251.         traceline (src, src + direction*2048, FALSE, self);
  252.         if (trace_fraction != 1.0)
  253.             TraceAttack (4, direction);
  254.  
  255.         shotcount = shotcount - 1;
  256.     }
  257.     ApplyMultiDamage ();
  258. };
  259.  
  260. /*
  261. ================
  262. W_FireShotgun
  263. ================
  264. */
  265. void() W_FireShotgun =
  266. {
  267.     local vector dir;
  268.  
  269.     sound (self, CHAN_WEAPON, "weapons/guncock.wav", 1, ATTN_NORM);    
  270.  
  271.     self.punchangle_x = -2;
  272.     
  273.     self.currentammo = self.ammo_shells = self.ammo_shells - 1;
  274.     dir = aim (self, 100000);
  275.     FireBullets (6, dir, '0.04 0.04 0');
  276. };
  277.  
  278.  
  279. /*
  280. ================
  281. W_FireSuperShotgun
  282. ================
  283. */
  284. void() W_FireSuperShotgun =
  285. {
  286.     local vector dir;
  287.  
  288.     if (self.currentammo == 1)
  289.     {
  290.         W_FireShotgun ();
  291.         return;
  292.     }
  293.         
  294.     sound (self ,CHAN_WEAPON, "weapons/shotgn2.wav", 1, ATTN_NORM);    
  295.  
  296.     self.punchangle_x = -4;
  297.     
  298.     self.currentammo = self.ammo_shells = self.ammo_shells - 2;
  299.     dir = aim (self, 100000);
  300.     FireBullets (14, dir, '0.14 0.08 0');
  301. };
  302.  
  303.  
  304. /*
  305. ==============================================================================
  306.  
  307. ROCKETS
  308.  
  309. ==============================================================================
  310. */
  311.  
  312. void()    s_explode1    =    [0,        s_explode2] {};
  313. void()    s_explode2    =    [1,        s_explode3] {};
  314. void()    s_explode3    =    [2,        s_explode4] {};
  315. void()    s_explode4    =    [3,        s_explode5] {};
  316. void()    s_explode5    =    [4,        s_explode6] {};
  317. void()    s_explode6    =    [5,        SUB_Remove] {};
  318.  
  319. void() BecomeExplosion =
  320. {
  321.     self.movetype = MOVETYPE_NONE;
  322.     self.velocity = '0 0 0';
  323.     self.touch = SUB_Null;
  324.     setmodel (self, "progs/s_explod.spr");
  325.     self.solid = SOLID_NOT;
  326.     s_explode1 ();
  327. };
  328.  
  329. void() T_MissileTouch =
  330. {
  331.     local float    damg;
  332.  
  333.     if (other == self.owner)
  334.         return;        // don't explode on owner
  335.  
  336.     if (pointcontents(self.origin) == CONTENT_SKY)
  337.     {
  338.         remove(self);
  339.         return;
  340.     }
  341.  
  342.     damg = 100 + random()*20;
  343.     
  344.     if (other.health)
  345.     {
  346.         if (other.classname == "monster_shambler")
  347.             damg = damg * 0.5;    // mostly immune
  348.         T_Damage (other, self, self.owner, damg );
  349.     }
  350.  
  351.     // don't do radius damage to the other, because all the damage
  352.     // was done in the impact
  353.     T_RadiusDamage (self, self.owner, 120, other);
  354.  
  355. //    sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
  356.     self.origin = self.origin - 8*normalize(self.velocity);
  357.  
  358.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  359.     WriteByte (MSG_BROADCAST, TE_EXPLOSION);
  360.     WriteCoord (MSG_BROADCAST, self.origin_x);
  361.     WriteCoord (MSG_BROADCAST, self.origin_y);
  362.     WriteCoord (MSG_BROADCAST, self.origin_z);
  363.  
  364.     BecomeExplosion ();
  365. };
  366.  
  367.  
  368.  
  369. /*
  370. ================
  371. W_FireRocket
  372. ================
  373. */
  374. void() W_FireRocket =
  375. {
  376.     local    entity missile, mpuff;
  377.     
  378.     self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
  379.     
  380.     sound (self, CHAN_WEAPON, "weapons/sgun1.wav", 1, ATTN_NORM);
  381.  
  382.     self.punchangle_x = -2;
  383.  
  384.     missile = spawn ();
  385.     missile.owner = self;
  386.     missile.movetype = MOVETYPE_FLYMISSILE;
  387.     missile.solid = SOLID_BBOX;
  388.     missile.classname = "missile";
  389.         
  390. // set missile speed    
  391.  
  392.     makevectors (self.v_angle);
  393.     missile.velocity = aim(self, 1000);
  394.     missile.velocity = missile.velocity * 1000;
  395.     missile.angles = vectoangles(missile.velocity);
  396.     
  397.     missile.touch = T_MissileTouch;
  398.     
  399. // set missile duration
  400.     missile.nextthink = time + 5;
  401.     missile.think = SUB_Remove;
  402.  
  403.     setmodel (missile, "progs/missile.mdl");
  404.     setsize (missile, '0 0 0', '0 0 0');        
  405.     setorigin (missile, self.origin + v_forward*8 + '0 0 16');
  406. };
  407.  
  408. /*
  409. ===============================================================================
  410.  
  411. LIGHTNING
  412.  
  413. ===============================================================================
  414. */
  415.  
  416. /*
  417. =================
  418. LightningDamage
  419. =================
  420. */
  421. void(vector p1, vector p2, entity from, float damage) LightningDamage =
  422. {
  423.     local entity        e1, e2;
  424.     local vector        f;
  425.     
  426.     f = p2 - p1;
  427.     normalize (f);
  428.     f_x = 0 - f_y;
  429.     f_y = f_x;
  430.     f_z = 0;
  431.     f = f*16;
  432.  
  433.     e1 = e2 = world;
  434.  
  435.     traceline (p1, p2, FALSE, self);
  436.     if (trace_ent.takedamage)
  437.     {
  438.         particle (trace_endpos, '0 0 100', 225, damage*4);
  439.         T_Damage (trace_ent, from, from, damage);
  440.         if (self.classname == "player")
  441.         {
  442.             if (other.classname == "player")
  443.                 trace_ent.velocity_z = trace_ent.velocity_z + 400;
  444.         }
  445.     }
  446.     e1 = trace_ent;
  447.  
  448.     traceline (p1 + f, p2 + f, FALSE, self);
  449.     if (trace_ent != e1 && trace_ent.takedamage)
  450.     {
  451.         particle (trace_endpos, '0 0 100', 225, damage*4);
  452.         T_Damage (trace_ent, from, from, damage);
  453.     }
  454.     e2 = trace_ent;
  455.  
  456.     traceline (p1 - f, p2 - f, FALSE, self);
  457.     if (trace_ent != e1 && trace_ent != e2 && trace_ent.takedamage)
  458.     {
  459.         particle (trace_endpos, '0 0 100', 225, damage*4);
  460.         T_Damage (trace_ent, from, from, damage);
  461.     }
  462. };
  463.  
  464.  
  465. void() W_FireLightning =
  466. {
  467.     local    vector        org;
  468.     local    float        cells;
  469.  
  470.     if (self.ammo_cells < 1)
  471.     {
  472.         self.weapon = W_BestWeapon ();
  473.         W_SetCurrentAmmo ();
  474.         return;
  475.     }
  476.  
  477. // explode if under water
  478.     if (self.waterlevel > 1)
  479.     {
  480.         cells = self.ammo_cells;
  481.         self.ammo_cells = 0;
  482.         W_SetCurrentAmmo ();
  483.         T_RadiusDamage (self, self, 35*cells, world);
  484.         return;
  485.     }
  486.  
  487.     if (self.t_width < time)
  488.     {
  489.         sound (self, CHAN_WEAPON, "weapons/lhit.wav", 1, ATTN_NORM);
  490.         self.t_width = time + 0.6;
  491.     }
  492.     self.punchangle_x = -2;
  493.  
  494.     self.currentammo = self.ammo_cells = self.ammo_cells - 1;
  495.  
  496.     org = self.origin + '0 0 16';
  497.     
  498.     traceline (org, org + v_forward*600, TRUE, self);
  499.  
  500.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  501.     WriteByte (MSG_BROADCAST, TE_LIGHTNING2);
  502.     WriteEntity (MSG_BROADCAST, self);
  503.     WriteCoord (MSG_BROADCAST, org_x);
  504.     WriteCoord (MSG_BROADCAST, org_y);
  505.     WriteCoord (MSG_BROADCAST, org_z);
  506.     WriteCoord (MSG_BROADCAST, trace_endpos_x);
  507.     WriteCoord (MSG_BROADCAST, trace_endpos_y);
  508.     WriteCoord (MSG_BROADCAST, trace_endpos_z);
  509.  
  510.     LightningDamage (self.origin, trace_endpos + v_forward*4, self, 30);
  511. };
  512.  
  513.  
  514. //=============================================================================
  515.  
  516.  
  517. void() GrenadeExplode =
  518. {
  519.     T_RadiusDamage (self, self.owner, 120, world);
  520.  
  521.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  522.     WriteByte (MSG_BROADCAST, TE_EXPLOSION);
  523.     WriteCoord (MSG_BROADCAST, self.origin_x);
  524.     WriteCoord (MSG_BROADCAST, self.origin_y);
  525.     WriteCoord (MSG_BROADCAST, self.origin_z);
  526.  
  527.     BecomeExplosion ();
  528. };
  529.  
  530. void() GrenadeTouch =
  531. {
  532.     if (other == self.owner)
  533.         return;        // don't explode on owner
  534.     if (other.takedamage == DAMAGE_AIM)
  535.     {
  536.         GrenadeExplode();
  537.         return;
  538.     }
  539.     sound (self, CHAN_WEAPON, "weapons/bounce.wav", 1, ATTN_NORM);    // bounce sound
  540.     if (self.velocity == '0 0 0')
  541.         self.avelocity = '0 0 0';
  542. };
  543.  
  544. /*
  545. ================
  546. W_FireGrenade
  547. ================
  548. */
  549. void() W_FireGrenade =
  550. {
  551.     local    entity missile, mpuff;
  552.     
  553.     self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
  554.     
  555.     sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);
  556.  
  557.     self.punchangle_x = -2;
  558.  
  559.     missile = spawn ();
  560.     missile.owner = self;
  561.     missile.movetype = MOVETYPE_BOUNCE;
  562.     missile.solid = SOLID_BBOX;
  563.     missile.classname = "grenade";
  564.         
  565. // set missile speed    
  566.  
  567.     makevectors (self.v_angle);
  568.  
  569.     if (self.v_angle_x)
  570.         missile.velocity = v_forward*600 + v_up * 200 + crandom()*v_right*10 + crandom()*v_up*10;
  571.     else
  572.     {
  573.         missile.velocity = aim(self, 10000);
  574.         missile.velocity = missile.velocity * 600;
  575.         missile.velocity_z = 200;
  576.     }
  577.  
  578.     missile.avelocity = '300 300 300';
  579.  
  580.     missile.angles = vectoangles(missile.velocity);
  581.     
  582.     missile.touch = GrenadeTouch;
  583.     
  584. // set missile duration
  585.     missile.nextthink = time + 2.5;
  586.     missile.think = GrenadeExplode;
  587.  
  588.     setmodel (missile, "progs/grenade.mdl");
  589.     setsize (missile, '0 0 0', '0 0 0');        
  590.     setorigin (missile, self.origin);
  591. };
  592.  
  593.  
  594. //=============================================================================
  595.  
  596. void() spike_touch;
  597. void() superspike_touch;
  598.  
  599.  
  600. /*
  601. ===============
  602. launch_spike
  603.  
  604. Used for both the player and the ogre
  605. ===============
  606. */
  607. void(vector org, vector dir) launch_spike =
  608. {
  609.     newmis = spawn ();
  610.     newmis.owner = self;
  611.     newmis.movetype = MOVETYPE_FLYMISSILE;
  612.     newmis.solid = SOLID_BBOX;
  613.  
  614.     newmis.angles = vectoangles(dir);
  615.     
  616.     newmis.touch = spike_touch;
  617.     newmis.classname = "spike";
  618.     newmis.think = SUB_Remove;
  619.     newmis.nextthink = time + 6;
  620.     setmodel (newmis, "progs/spike.mdl");
  621.     setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);        
  622.     setorigin (newmis, org);
  623.  
  624.     newmis.velocity = dir * 1000;
  625. };
  626.  
  627. void() W_FireSuperSpikes =
  628. {
  629.     local vector    dir;
  630.     local entity    old;
  631.     
  632.     sound (self, CHAN_WEAPON, "weapons/spike2.wav", 1, ATTN_NORM);
  633.     self.attack_finished = time + 0.2;
  634.     self.currentammo = self.ammo_nails = self.ammo_nails - 2;
  635.     dir = aim (self, 1000);
  636.     launch_spike (self.origin + '0 0 16', dir);
  637.     newmis.touch = superspike_touch;
  638.     setmodel (newmis, "progs/s_spike.mdl");
  639.     setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);        
  640.     self.punchangle_x = -2;
  641. };
  642.  
  643. void(float ox) W_FireSpikes =
  644. {
  645.     local vector    dir;
  646.     local entity    old;
  647.     
  648.     makevectors (self.v_angle);
  649.     
  650.     if (self.ammo_nails >= 2 && self.weapon == IT_SUPER_NAILGUN)
  651.     {
  652.         W_FireSuperSpikes ();
  653.         return;
  654.     }
  655.  
  656.     if (self.ammo_nails < 1)
  657.     {
  658.         self.weapon = W_BestWeapon ();
  659.         W_SetCurrentAmmo ();
  660.         return;
  661.     }
  662.  
  663.     sound (self, CHAN_WEAPON, "weapons/rocket1i.wav", 1, ATTN_NORM);
  664.     self.attack_finished = time + 0.2;
  665.     self.currentammo = self.ammo_nails = self.ammo_nails - 1;
  666.     dir = aim (self, 1000);
  667.     launch_spike (self.origin + '0 0 16' + v_right*ox, dir);
  668.  
  669.     self.punchangle_x = -2;
  670. };
  671.  
  672.  
  673.  
  674. .float hit_z;
  675. void() spike_touch =
  676. {
  677. local float rand;
  678.     if (other == self.owner)
  679.         return;
  680.  
  681.     if (other.solid == SOLID_TRIGGER)
  682.         return;    // trigger field, do nothing
  683.  
  684.     if (pointcontents(self.origin) == CONTENT_SKY)
  685.     {
  686.         remove(self);
  687.         return;
  688.     }
  689.     
  690. // hit something that bleeds
  691.     if (other.takedamage)
  692.     {
  693.         spawn_touchblood (9);
  694.         T_Damage (other, self, self.owner, 9);
  695.     }
  696.     else
  697.     {
  698.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  699.         
  700.         if (self.classname == "wizspike")
  701.             WriteByte (MSG_BROADCAST, TE_WIZSPIKE);
  702.         else if (self.classname == "knightspike")
  703.             WriteByte (MSG_BROADCAST, TE_KNIGHTSPIKE);
  704.         else
  705.             WriteByte (MSG_BROADCAST, TE_SPIKE);
  706.         WriteCoord (MSG_BROADCAST, self.origin_x);
  707.         WriteCoord (MSG_BROADCAST, self.origin_y);
  708.         WriteCoord (MSG_BROADCAST, self.origin_z);
  709.     }
  710.  
  711.     remove(self);
  712.  
  713. };
  714.  
  715. void() superspike_touch =
  716. {
  717. local float rand;
  718.     if (other == self.owner)
  719.         return;
  720.  
  721.     if (other.solid == SOLID_TRIGGER)
  722.         return;    // trigger field, do nothing
  723.  
  724.     if (pointcontents(self.origin) == CONTENT_SKY)
  725.     {
  726.         remove(self);
  727.         return;
  728.     }
  729.     
  730. // hit something that bleeds
  731.     if (other.takedamage)
  732.     {
  733.         spawn_touchblood (18);
  734.         T_Damage (other, self, self.owner, 18);
  735.     }
  736.     else
  737.     {
  738.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  739.         WriteByte (MSG_BROADCAST, TE_SUPERSPIKE);
  740.         WriteCoord (MSG_BROADCAST, self.origin_x);
  741.         WriteCoord (MSG_BROADCAST, self.origin_y);
  742.         WriteCoord (MSG_BROADCAST, self.origin_z);
  743.     }
  744.  
  745.     remove(self);
  746.  
  747. };
  748.  
  749.  
  750. /*
  751. ===============================================================================
  752.  
  753. PLAYER WEAPON USE
  754.  
  755. ===============================================================================
  756. */
  757.  
  758. void() W_SetCurrentAmmo =
  759. {
  760.     player_run ();        // get out of any weapon firing states
  761.  
  762.     self.items = self.items - ( self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS) );
  763.     
  764.     if (self.weapon == IT_AXE)
  765.     {
  766.         self.currentammo = 0;
  767.         self.weaponmodel = "progs/v_axe.mdl";
  768.         self.weaponframe = 0;
  769.     }
  770.     else if (self.weapon == IT_SHOTGUN)
  771.     {
  772.         self.currentammo = self.ammo_shells;
  773.         self.weaponmodel = "progs/v_shot.mdl";
  774.         self.weaponframe = 0;
  775.         self.items = self.items | IT_SHELLS;
  776.     }
  777.     else if (self.weapon == IT_SUPER_SHOTGUN)
  778.     {
  779.         self.currentammo = self.ammo_shells;
  780.         self.weaponmodel = "progs/v_shot2.mdl";
  781.         self.weaponframe = 0;
  782.         self.items = self.items | IT_SHELLS;
  783.     }
  784.     else if (self.weapon == IT_NAILGUN)
  785.     {
  786.         self.currentammo = self.ammo_nails;
  787.         self.weaponmodel = "progs/v_nail.mdl";
  788.         self.weaponframe = 0;
  789.         self.items = self.items | IT_NAILS;
  790.     }
  791.     else if (self.weapon == IT_SUPER_NAILGUN)
  792.     {
  793.         self.currentammo = self.ammo_nails;
  794.         self.weaponmodel = "progs/v_nail2.mdl";
  795.         self.weaponframe = 0;
  796.         self.items = self.items | IT_NAILS;
  797.     }
  798.     else if (self.weapon == IT_GRENADE_LAUNCHER)
  799.     {
  800.         self.currentammo = self.ammo_rockets;
  801.         self.weaponmodel = "progs/v_rock.mdl";
  802.         self.weaponframe = 0;
  803.         self.items = self.items | IT_ROCKETS;
  804.     }
  805.     else if (self.weapon == IT_ROCKET_LAUNCHER)
  806.     {
  807.         self.currentammo = self.ammo_rockets;
  808.         self.weaponmodel = "progs/v_rock2.mdl";
  809.         self.weaponframe = 0;
  810.         self.items = self.items | IT_ROCKETS;
  811.     }
  812.     else if (self.weapon == IT_LIGHTNING)
  813.     {
  814.         self.currentammo = self.ammo_cells;
  815.         self.weaponmodel = "progs/v_light.mdl";
  816.         self.weaponframe = 0;
  817.         self.items = self.items | IT_CELLS;
  818.     }
  819.     else
  820.     {
  821.         self.currentammo = 0;
  822.         self.weaponmodel = "";
  823.         self.weaponframe = 0;
  824.     }
  825. };
  826.  
  827. float() W_BestWeapon =
  828. {
  829.     local    float    it;
  830.     
  831.     it = self.items;
  832.  
  833.     if (self.waterlevel <= 1 && self.ammo_cells >= 1 && (it & IT_LIGHTNING) )
  834.             return IT_LIGHTNING;
  835.     if(self.ammo_nails >= 2 && (it & IT_SUPER_NAILGUN) )
  836.         return IT_SUPER_NAILGUN;
  837.     if(self.ammo_shells >= 2 && (it & IT_SUPER_SHOTGUN) )
  838.         return IT_SUPER_SHOTGUN;
  839.     if(self.ammo_nails >= 1 && (it & IT_NAILGUN) )
  840.         return IT_NAILGUN;
  841.     if(self.ammo_shells >= 1 && (it & IT_SHOTGUN) )
  842.         return IT_SHOTGUN;
  843.     return IT_AXE;
  844. };
  845.  
  846. float() W_CheckNoAmmo =
  847. {
  848.     if (self.currentammo > 0)
  849.         return TRUE;
  850.  
  851.     if (self.weapon == IT_AXE)
  852.         return TRUE;
  853.     
  854.     self.weapon = W_BestWeapon ();
  855.  
  856.     W_SetCurrentAmmo ();
  857.     
  858. // drop the weapon down
  859.     return FALSE;
  860. };
  861.  
  862. /*
  863. ============
  864. W_Attack
  865.  
  866. An attack impulse can be triggered now
  867. ============
  868. */
  869. void()    player_axe1;
  870. void()    player_axeb1;
  871. void()    player_axec1;
  872. void()    player_axed1;
  873. void()    player_shot1;
  874. void()    player_nail1;
  875. void()    player_light1;
  876. void()    player_rocket1;
  877.  
  878. void() W_Attack =
  879. {
  880.     local    float    r;
  881.  
  882.     if (!W_CheckNoAmmo ())
  883.         return;
  884.  
  885.     makevectors    (self.v_angle);            // calculate forward angle for velocity
  886.     self.show_hostile = time + 1;    // wake monsters up
  887.  
  888.     if (self.weapon == IT_AXE)
  889.     {
  890.         sound (self, CHAN_WEAPON, "weapons/ax1.wav", 1, ATTN_NORM);
  891.         r = random();
  892.         if (r < 0.25)
  893.             player_axe1 ();
  894.         else if (r<0.5)
  895.             player_axeb1 ();
  896.         else if (r<0.75)
  897.             player_axec1 ();
  898.         else
  899.             player_axed1 ();
  900.         self.attack_finished = time + 0.5;
  901.     }
  902.     else if (self.weapon == IT_SHOTGUN)
  903.     {
  904.         player_shot1 ();
  905.         W_FireShotgun ();
  906.         self.attack_finished = time + 0.5;
  907.     }
  908.     else if (self.weapon == IT_SUPER_SHOTGUN)
  909.     {
  910.         player_shot1 ();
  911.         W_FireSuperShotgun ();
  912.         self.attack_finished = time + 0.7;
  913.     }
  914.     else if (self.weapon == IT_NAILGUN)
  915.     {
  916.         player_nail1 ();
  917.     }
  918.     else if (self.weapon == IT_SUPER_NAILGUN)
  919.     {
  920.         player_nail1 ();
  921.     }
  922.     else if (self.weapon == IT_GRENADE_LAUNCHER)
  923.     {
  924.         player_rocket1();
  925.         W_FireGrenade();
  926.         self.attack_finished = time + 0.6;
  927.     }
  928.     else if (self.weapon == IT_ROCKET_LAUNCHER)
  929.     {
  930.         player_rocket1();
  931.         W_FireRocket();
  932.         self.attack_finished = time + 0.8;
  933.     }
  934.     else if (self.weapon == IT_LIGHTNING)
  935.     {
  936.         player_light1();
  937.         self.attack_finished = time + 0.1;
  938.         sound (self, CHAN_AUTO, "weapons/lstart.wav", 1, ATTN_NORM);
  939.     }
  940. };
  941.  
  942. /*
  943. ============
  944. W_ChangeWeapon
  945.  
  946. ============
  947. */
  948. void() W_ChangeWeapon =
  949. {
  950.     local    float    it, am, fl;
  951.     
  952.     it = self.items;
  953.     am = 0;
  954.     
  955.     if (self.impulse == 1)
  956.     {
  957.         fl = IT_AXE;
  958.     }
  959.     else if (self.impulse == 2)
  960.     {
  961.         fl = IT_SHOTGUN;
  962.         if (self.ammo_shells < 1)
  963.             am = 1;
  964.     }
  965.     else if (self.impulse == 3)
  966.     {
  967.         fl = IT_SUPER_SHOTGUN;
  968.         if (self.ammo_shells < 2)
  969.             am = 1;
  970.     }        
  971.     else if (self.impulse == 4)
  972.     {
  973.         fl = IT_NAILGUN;
  974.         if (self.ammo_nails < 1)
  975.             am = 1;
  976.     }
  977.     else if (self.impulse == 5)
  978.     {
  979.         fl = IT_SUPER_NAILGUN;
  980.         if (self.ammo_nails < 2)
  981.             am = 1;
  982.     }
  983.     else if (self.impulse == 6)
  984.     {
  985.         fl = IT_GRENADE_LAUNCHER;
  986.         if (self.ammo_rockets < 1)
  987.             am = 1;
  988.     }
  989.     else if (self.impulse == 7)
  990.     {
  991.         fl = IT_ROCKET_LAUNCHER;
  992.         if (self.ammo_rockets < 1)
  993.             am = 1;
  994.     }
  995.     else if (self.impulse == 8)
  996.     {
  997.         fl = IT_LIGHTNING;
  998.         if (self.ammo_cells < 1)
  999.             am = 1;
  1000.     }
  1001.  
  1002.     self.impulse = 0;
  1003.     
  1004.     if (!(self.items & fl))
  1005.     {    // don't have the weapon or the ammo
  1006.         sprint (self, "no weapon.\n");
  1007.         return;
  1008.     }
  1009.     
  1010.     if (am)
  1011.     {    // don't have the ammo
  1012.         sprint (self, "not enough ammo.\n");
  1013.         return;
  1014.     }
  1015.  
  1016. //
  1017. // set weapon, set ammo
  1018. //
  1019.     self.weapon = fl;        
  1020.     W_SetCurrentAmmo ();
  1021. };
  1022.  
  1023. /*
  1024. ============
  1025. CheatCommand
  1026. ============
  1027. */
  1028. void() CheatCommand =
  1029. {
  1030.     if (deathmatch || coop)
  1031.         return;
  1032.  
  1033.     self.ammo_rockets = 100;
  1034.     self.ammo_nails = 200;
  1035.     self.ammo_shells = 100;
  1036.     self.items = self.items | 
  1037.         IT_AXE |
  1038.         IT_SHOTGUN |
  1039.         IT_SUPER_SHOTGUN |
  1040.         IT_NAILGUN |
  1041.         IT_SUPER_NAILGUN |
  1042.         IT_GRENADE_LAUNCHER |
  1043.         IT_ROCKET_LAUNCHER |
  1044.         IT_KEY1 | IT_KEY2;
  1045.  
  1046.     self.ammo_cells = 200;
  1047.     self.items = self.items | IT_LIGHTNING;
  1048.  
  1049.     self.weapon = IT_ROCKET_LAUNCHER;
  1050.     self.impulse = 0;
  1051.     W_SetCurrentAmmo ();
  1052. };
  1053.  
  1054. /*
  1055. ============
  1056. CycleWeaponCommand
  1057.  
  1058. Go to the next weapon with ammo
  1059. ============
  1060. */
  1061. void() CycleWeaponCommand =
  1062. {
  1063.     local    float    it, am;
  1064.     
  1065.     it = self.items;
  1066.     self.impulse = 0;
  1067.     
  1068.     while (1)
  1069.     {
  1070.         am = 0;
  1071.  
  1072.         if (self.weapon == IT_LIGHTNING)
  1073.         {
  1074.             self.weapon = IT_AXE;
  1075.         }
  1076.         else if (self.weapon == IT_AXE)
  1077.         {
  1078.             self.weapon = IT_SHOTGUN;
  1079.             if (self.ammo_shells < 1)
  1080.                 am = 1;
  1081.         }
  1082.         else if (self.weapon == IT_SHOTGUN)
  1083.         {
  1084.             self.weapon = IT_SUPER_SHOTGUN;
  1085.             if (self.ammo_shells < 2)
  1086.                 am = 1;
  1087.         }        
  1088.         else if (self.weapon == IT_SUPER_SHOTGUN)
  1089.         {
  1090.             self.weapon = IT_NAILGUN;
  1091.             if (self.ammo_nails < 1)
  1092.                 am = 1;
  1093.         }
  1094.         else if (self.weapon == IT_NAILGUN)
  1095.         {
  1096.             self.weapon = IT_SUPER_NAILGUN;
  1097.             if (self.ammo_nails < 2)
  1098.                 am = 1;
  1099.         }
  1100.         else if (self.weapon == IT_SUPER_NAILGUN)
  1101.         {
  1102.             self.weapon = IT_GRENADE_LAUNCHER;
  1103.             if (self.ammo_rockets < 1)
  1104.                 am = 1;
  1105.         }
  1106.         else if (self.weapon == IT_GRENADE_LAUNCHER)
  1107.         {
  1108.             self.weapon = IT_ROCKET_LAUNCHER;
  1109.             if (self.ammo_rockets < 1)
  1110.                 am = 1;
  1111.         }
  1112.         else if (self.weapon == IT_ROCKET_LAUNCHER)
  1113.         {
  1114.             self.weapon = IT_LIGHTNING;
  1115.             if (self.ammo_cells < 1)
  1116.                 am = 1;
  1117.         }
  1118.     
  1119.         if ( (it & self.weapon) && am == 0)
  1120.         {
  1121.             W_SetCurrentAmmo ();
  1122.             return;
  1123.         }
  1124.     }
  1125.  
  1126. };
  1127.  
  1128. /*
  1129. ============
  1130. CycleWeaponReverseCommand
  1131.  
  1132. Go to the prev weapon with ammo
  1133. ============
  1134. */
  1135. void() CycleWeaponReverseCommand =
  1136. {
  1137.     local    float    it, am;
  1138.     
  1139.     it = self.items;
  1140.     self.impulse = 0;
  1141.  
  1142.     while (1)
  1143.     {
  1144.         am = 0;
  1145.  
  1146.         if (self.weapon == IT_LIGHTNING)
  1147.         {
  1148.             self.weapon = IT_ROCKET_LAUNCHER;
  1149.             if (self.ammo_rockets < 1)
  1150.                 am = 1;
  1151.         }
  1152.         else if (self.weapon == IT_ROCKET_LAUNCHER)
  1153.         {
  1154.             self.weapon = IT_GRENADE_LAUNCHER;
  1155.             if (self.ammo_rockets < 1)
  1156.                 am = 1;
  1157.         }
  1158.         else if (self.weapon == IT_GRENADE_LAUNCHER)
  1159.         {
  1160.             self.weapon = IT_SUPER_NAILGUN;
  1161.             if (self.ammo_nails < 2)
  1162.                 am = 1;
  1163.         }
  1164.         else if (self.weapon == IT_SUPER_NAILGUN)
  1165.         {
  1166.             self.weapon = IT_NAILGUN;
  1167.             if (self.ammo_nails < 1)
  1168.                 am = 1;
  1169.         }
  1170.         else if (self.weapon == IT_NAILGUN)
  1171.         {
  1172.             self.weapon = IT_SUPER_SHOTGUN;
  1173.             if (self.ammo_shells < 2)
  1174.                 am = 1;
  1175.         }        
  1176.         else if (self.weapon == IT_SUPER_SHOTGUN)
  1177.         {
  1178.             self.weapon = IT_SHOTGUN;
  1179.             if (self.ammo_shells < 1)
  1180.                 am = 1;
  1181.         }
  1182.         else if (self.weapon == IT_SHOTGUN)
  1183.         {
  1184.             self.weapon = IT_AXE;
  1185.         }
  1186.         else if (self.weapon == IT_AXE)
  1187.         {
  1188.             self.weapon = IT_LIGHTNING;
  1189.             if (self.ammo_cells < 1)
  1190.                 am = 1;
  1191.         }
  1192.     
  1193.         if ( (it & self.weapon) && am == 0)
  1194.         {
  1195.             W_SetCurrentAmmo ();
  1196.             return;
  1197.         }
  1198.     }
  1199.  
  1200. };
  1201.  
  1202. /*
  1203. ============
  1204. ServerflagsCommand
  1205.  
  1206. Just for development
  1207. ============
  1208. */
  1209. void() ServerflagsCommand =
  1210. {
  1211.     serverflags = serverflags * 2 + 1;
  1212. };
  1213.  
  1214. void() QuadCheat =
  1215. {
  1216.     if (deathmatch || coop)
  1217.         return;
  1218.     self.super_time = 1;
  1219.     self.super_damage_finished = time + 30;
  1220.     self.items = self.items | IT_QUAD;
  1221.     dprint ("quad cheat\n");
  1222. };
  1223.  
  1224. /*
  1225. ============
  1226. ImpulseCommands
  1227.  
  1228. ============
  1229. */
  1230. void() ImpulseCommands =
  1231. {
  1232.     if (self.impulse >= 1 && self.impulse <= 8)
  1233.         W_ChangeWeapon ();
  1234.  
  1235.     if (self.impulse == 9)
  1236.         CheatCommand ();
  1237.     if (self.impulse == 10)
  1238.         CycleWeaponCommand ();
  1239.     if (self.impulse == 11)
  1240.         ServerflagsCommand ();
  1241.     if (self.impulse == 12)
  1242.         CycleWeaponReverseCommand ();
  1243.  
  1244.     if (self.impulse == 255)
  1245.         QuadCheat ();
  1246.         
  1247.     self.impulse = 0;
  1248. };
  1249.  
  1250. /*
  1251. ============
  1252. W_WeaponFrame
  1253.  
  1254. Called every frame so impulse events can be handled as well as possible
  1255. ============
  1256. */
  1257. void() W_WeaponFrame =
  1258. {
  1259.     if (time < self.attack_finished)
  1260.         return;
  1261.  
  1262.     ImpulseCommands ();
  1263.     
  1264. // check for attack
  1265.     if (self.button0)
  1266.     {
  1267.         SuperDamageSound ();
  1268.         W_Attack ();
  1269.     }
  1270. };
  1271.  
  1272. /*
  1273. ========
  1274. SuperDamageSound
  1275.  
  1276. Plays sound if needed
  1277. ========
  1278. */
  1279. void() SuperDamageSound =
  1280. {
  1281.     if (self.super_damage_finished > time)
  1282.     {
  1283.         if (self.super_sound < time)
  1284.         {
  1285.             self.super_sound = time + 1;
  1286.             sound (self, CHAN_BODY, "items/damage3.wav", 1, ATTN_NORM);
  1287.         }
  1288.     }
  1289.     return;
  1290. };
  1291.  
  1292.  
  1293.